Créez votre tableur de budget mensuel avec Visuel Annuel sur Google Sheets depuis zéro. Vingt-et-une étapes expliquées posément, avec une capture du rendu final à chaque étape clé.
Ouvrez votre navigateur et allez sur google.com.
Cliquez sur l'icône des 9 points (menu Google) en haut à droite, à côté de votre photo de profil.
Si vous choisissez Google Drive : cliquez sur Nouveau en haut à gauche → sélectionnez Google Sheets → puis Feuille de calcul vierge.
Si vous choisissez Google Sheets directement : cliquez sur la grande carte avec le symbole + pour créer une nouvelle feuille de calcul.
En haut à gauche, cliquez sur Feuille de calcul sans titre.
Donnez un nom à votre fichier, par exemple Budget 2026.
La première page de votre tableur : le suivi complet d'un mois de budget.
Dans votre feuille Google Sheets, repérez les cellules où seront placés les différents cadres. Nous allons en créer 6 : Résumé, Revenus, Prélèvements automatiques, Budget prévu, Dépenses du mois, et Date.
Sélectionnez les cellules B14:E29.
Dans le menu Bordures, choisissez Couleur de la bordure, Personnaliser #cad9e5, Style de la bordure, trait simple (2ème option en haut), Bordures extérieures.
Sélectionnez les cellules B31:E39. Bordures, Couleur de la bordure #c4ecda, Bordures extérieures.
E35.Sélectionnez les cellules G14:K50. Bordures, Couleur de la bordure #f7cec3, Bordures extérieures.
Sélectionnez M14:Q50. Bordures, Couleur de la bordure #f7deb6, Bordures extérieures.
Sélectionnez S14:W50. Bordures, Couleur de la bordure #bcdefa, Bordures extérieures.
Sélectionnez B41:E50. Fusionnez d'abord les cellules (Format > Fusionner les cellules > Tout fusionner) pour créer un grand espace unique. Ou cliquez directement sur le bouton Fusionner les cellules en haut dans la barre d'outils.
Puis Bordures, Couleur de la bordure #666666, Style de la bordure, 1er trait, Bordures extérieures. 1
Sélectionnez le petit carré à l'intersection de la colonne A et de la ligne 1 → cela sélectionne toute la feuille.
Cliquez sur Aligner horizontalement → Centre.
Cliquez sur Aligner verticalement → Milieu.
B14:E15 → tapez RésuméB31:E32 → tapez RevenusG14:K15 → tapez Prélèvements AutomatiquesM14:Q15 → tapez Budget PrévuS14:W15 → tapez Dépenses du MoisMettez ces titres en gras et en taille 14.
Pour le cadre Date, sélectionnez-le et mettez en gras et en taille 37.
Ctrl + B = gras · Ctrl + U = soulignerFusionnez les cellules suivantes :
B16:C17, B18:C19, B20:C21, B22:C23, B24:C25, B26:C27, B28:C29
D16:E17, D18:E19, D20:E21, D22:E23, D24:E25, D26:E27, D28:E29
Libellés à saisir (colonne gauche) : Revenus, Prélèvements Automatiques, Budget Prévu, Dépenses du Mois, Dépenses Totales Prévues, Report Mois Précédent, Budget Disponible Restant.
Mettez les libellés et les cellules associées en gras, taille 12, sauf Budget disponible restant en taille 13.
Dans le cadre Revenus, saisissez Total : en C33. Mettez-le en gras, italique, taille 12, aligné à droite.
Copiez cette cellule puis collez-la dans : I16 (Prélèvements), M16 (Budget prévu), V16 (Dépenses du Mois).
Vérifiez la bordure gauche M16, elle a sûrement disparu en collant → remettez-la si besoin (Bordures, Couleur #f7deb6, Style 2ème trait, Bordure gauche).
Redimensionnez les lignes 16 et 33. Clic droit, Redimensionner les lignes sélectionnées, Spécifier la hauteur de ligne, 21, OK.
B34:E34) : Nom, Source, Mensuel, Annuel (en gras)G17:K17) : Nom, (H17 vide), Catégorie, Mensuel, Annuel (en gras)M17:Q17) : Catégorie, Mensuel, Annuel, Actuel, Restant (en gras)S17:W17) : Date, Jour, Nom, Catégorie, Montant (en gras)Supprimez les colonnes Y et Z : sélectionnez Y → Ctrl + clic sur Z → clic droit → Supprimer les colonnes sélectionnées.
Supprimez les lignes à partir de 101 : sélectionnez la ligne 101 → Ctrl + Shift + ↓ → clic droit → Supprimer les lignes 101 – 1000.
Sélectionnez les colonnes A, F, H, L, R, X → clic droit → Redimensionner → 30.
Ajustez les autres colonnes :
Résumé B14:E15, Couleur de remplissage, Personnaliser → #cad9e5
Revenus B16:C17, B31:E32, B34:E34 → #c4ecda
Prélèvements Automatiques B18:C19, G14:K15, G17:K17 → #f7cec3
Budget Prévu B20:C21, M14:Q15, M17:Q17 → #f7deb6
Dépenses du Mois B22:C23, S14:W15, S17:W17 → #bcdefa
Dépenses Totales Prévues B24:C25 → #ddeaf2
Report Mois Précédent B26:C27 → #f0d8ec
Budget Disponible Restant B28:C29 → #d2c4e3
Et pour les cellules des montants du cadre Résumé :
D16:E17 #d6f2e6 · D18:E19 #fae0d6 · D20:E21 #fae8cc · D22:E23 #d0e8fc · D24:E25 #eef4f9 · D26:E27 #f9eef5 · D28:E29 #dfd4ed
Résumé B14:E15 → #2a4a5a
Revenus B16:E17, B31:E32, B34:E34 → #1a5e3f
Prélèvements Automatiques B18:E19, G14:K15, G17:K17 → #7a2e1a
Budget Prévu B20:E21, M14:Q15, M17:Q17 → #7a4400
Dépenses du Mois B22:E23, S14:W15, S17:W17 → #1a3f7a
Dépenses Totales Prévues B24:E25 → #6a8a9a
Report Mois Précédent B26:C27 → #9a5878
Budget Disponible Restant B28:C29 → #4a2e7a
C33:E33, B35:B39, D35:E39, B41:E50, I16:K16, G18:G50, J18:K50, M16:P16, N18:P50, V16, S18:U50, W18:W50 → #434343 (gris foncé 4)
Couleur de remplissage des cellules de formules en #f7f7f7 :
B33:E33, E35:E39, G16:K16, K18:K50, M16:Q16, O18:Q50, S16:W16, S18:S50
Désactivez le quadrillage → menu Affichage > Afficher > Quadrillage.
Ajoutez des bordures intérieures en gris clair 2 (#efefef), Style 1er trait, dans les zones blanches :
B35:D39, G18:J50, M18:N50, T18:W50
Ajoutez des bordures intérieures en blanc #ffffff dans les zones colorées :
B14:E29, B31:E34, E35:E39, G14:K17, K18:K50, M14:Q17, O18:Q50, S14:W17, S18:S50
Corrigez les décalages en ajoutant une bordure blanche inférieure sur les lignes de libellés :
B34:E34, G17:K17, M17:Q17, S17:W17
Réactivez le quadrillage → Affichage > Afficher > Quadrillage. 3
Cliquez sur le cadre de la Date (B41:E50).
Menu Données > Validation des données > Ajouter une règle.
Dans Critères, choisissez Est une date correcte → OK.
Double-cliquez dans la cellule → un calendrier s'ouvre.
Choisissez le mois qui vous intéresse (ex. Septembre si vous commencez en Septembre).
Menu Format > Nombre > Date et heure personnalisées.
Choisissez un affichage simplifié du type "août 1930".
Personnalisez l'affichage en cliquant sur la petite flèche si nécessaire → Appliquer. 7
Dans la colonne Nom (B35:B39), saisissez vos sources de revenus. Alignez les cellules à gauche.
Dans la colonne Mensuel (D35:D39), entrez leurs montants exacts.
Calculez le Total Mensuel en D33 : =SOMME(D35:D39)
SOMME additionne tous les montants de la plage sélectionnée.
Calculez l'Annuel en E35 : =MULTIPLY(12;D35)
MULTIPLY multiplie le montant mensuel par 12 pour obtenir le montant annuel.
=D35*12 → ça revient au même.Pour appliquer la formule aux autres cellules, cliquez sur E35 et glissez le petit rond en bas à droite jusqu'à E39.
Copiez la formule de l'Annuel Total (E33) en glissant depuis D33. Remettez les bordures (Couleur #c4ecda, 2ème trait simple, Bordure droite pour E33, Bordure inférieure pour E39). Et vous pouvez redimensionner à 21 pixels, la ligne 39 qui a été agrandie avec la bordure remise.
Dans la colonne Nom (G18:G50), saisissez vos charges fixes. Alignez à gauche.
Exemples : Voiture, Internet, Assurance, Électricité, etc.
Dans la colonne Mensuel (J18:J50), saisissez les montants.
Calculez l'Annuel en K18 : =MULTIPLY(12;J18)
Glissez la formule vers le bas (K18:K50).
Calculez les Totaux avec =SOMME(J18:J50) en J16, puis glissez en K16.
Remettez les bordures (Couleur #f7cec3, 2ème trait simple, Bordure droite pour K16, Bordure inférieure pour K50).
Dans la colonne Catégorie (M18:M50), saisissez vos catégories.
Exemples :
🐾 Croquettes #a878d8 · 🎉 Plaisirs #c8c040 · 🩷 Santé #e878b8 · ⛽ Essence #e09a50 · 📦 Autre #434343 · 🛒 Courses #e07878 · 🛍️ Vêtements #6098e0 · 🌿 Entretien Jardin #6ec860 · ✂️ Coiffeur #40b8b8
Saisissez vos budgets mensuels correspondants.
Calculez l'Annuel dans O18 : =MULTIPLY(12;N18)
Glissez vers le bas jusqu'à O50. Calculez les Totaux en N16 avec =SOMME(N18:N50), puis glissez jusqu'en Q16.
Remettez les bordures (Couleur #f7deb6, 2ème trait simple, Bordure droite pour Q16, Bordure inférieure pour O50).
Pour trier : sélectionnez votre plage (M18:N50 ici) → clic droit → Afficher plus d'actions sur les cellules → Trier une plage → Colonne N, De Z à A → Trier.
Ajoutez uniquement le Total en W16 : =SOMME(W18:W)
Grâce à :W sans numéro de fin, le calcul inclura toujours les nouvelles lignes que vous ajouterez.
Reliez les cellules aux totaux des autres tableaux :
Revenus D16:E17 → =D33 — Affiche le total de vos revenus mensuels.
Prélèvements D18:E19 → =J16 — Affiche le total de vos prélèvements automatiques.
Budget Prévu D20:E21 → =N16 — Affiche le total de votre budget prévu.
Dépenses du Mois D22:E23 → =W16 — Affiche le total de vos dépenses réelles.
Dépenses Totales Prévues D24:E25 → =J16+N16 + Clic droit sur D24:E25 → Insérer une remarque → Somme des prélèvements et du budget prévu.
Additionne vos prélèvements et votre budget prévu pour obtenir le total de vos dépenses prévisionnelles.
Report Mois Précédent B52 → =NOMPROPRE(TEXTE(FIN.MOIS(B41;-1);"mmmm"))
Décortiquons cette formule :
NOMPROPRE met la première lettre en majuscule. « juillet » devient « Juillet », ce qui correspond au nom de notre onglet.
TEXTE(… ; "mmmm") transforme cette date en texte — le nom du mois en entier. Le nombre de « m » change le résultat : "m" donne le numéro (7), "mm" le numéro avec un zéro (07), "mmm" l'abrégé (sept.), et "mmmm" le nom complet (septembre).
FIN.MOIS(B41 ; -1) prend notre date et recule d'un mois. Si B41 est en août, on obtient le 31 juillet.
&" "&ANNEE(FIN.MOIS(B41;-1)) à la fin de la formule. Le & colle les morceaux de texte entre eux, et " " ajoute un espace — sans lui, on obtiendrait « Juillet2026 ».Mettez le texte de B52 en blanc pour le masquer.
Puis Données → Protéger des feuilles et des plages → Formule Date → Définir les autorisations → Afficher un avertissement → OK.
Report Mois Précédent D26:E27 → =SIERREUR(SI(INDIRECT("'"&$B$52&"'!D22")=0;"";INDIRECT("'"&$B$52&"'!D28"));"")
Décortiquons cette formule. Au lieu d'écrire le nom du mois nous-mêmes comme on le faisait avant, on demande à la formule d'aller le chercher dans B52.
"'"&$B$52&"'!D22" construit un texte en collant 4 morceaux avec le & : une apostrophe, le nom du mois lu dans B52, une apostrophe, puis !D22. Si B52 contient « Juillet », on obtient 'Juillet'!D22. C'est juste du texte pour l'instant — Google Sheets ne fait rien avec.
INDIRECT(…) dit à Google Sheets : « ce texte, traite-le comme une vraie adresse de cellule ». Google Sheets va réellement ouvrir l'onglet Juillet et lire ce qu'il y a dans D22.
SI(…=0 ; "" ; …) a toujours 3 parties : la question, la réponse si oui, la réponse si non. La question : est-ce que les dépenses du mois précédent (D22) sont à 0 ? Si oui, on laisse vide — le mois n'a pas été utilisé. Si non, le deuxième INDIRECT va chercher D28, le Budget Disponible Restant du mois précédent.
SIERREUR(… ; "") protège contre l'erreur si l'onglet du mois précédent n'existe pas encore — la cellule reste vide au lieu d'afficher une erreur.
Quand vous dupliquerez cette page pour un nouveau mois, il suffira de changer la date en B41 — le report suivra automatiquement, sans toucher à aucune formule.
Budget Disponible Restant D28:E29 → =D16+D26-D18-D22 + Clic droit → Insérer une remarque → Revenus + Report Mois Précédent - Prélèvements Automatiques - Dépenses du Mois.
C'est votre solde réel : revenus + report du mois précédent − prélèvements − dépenses.
Mettez en gras et italique les totaux : D16:E29, D33:E33, J16:K16, N16:Q16, W16.
Taille de police 11 pour D33:E33, J16:K16, N16:Q16, W16. 4
Sélectionnez C35:C39 → Données > Validation des données > Ajouter une règle.
Cliquez sur Options avancées → Style d'affichage : Flèche.
Entrez vos options (Ajouter un autre élément).
Exemples : 💼 Employeur · 💼 Employeur 2 · 💼 Employeur 3 · 💻 Freelance · 📈 Dividende · 🏛️ Allocations · 🏠 Loyer perçu · 🎯 Prime · 💸 Remboursement · 🛒 Vente · 🎓 Retraite · 🎓 Retraite 2 · 📦 Autre · 👨💼 Client 1 · 👨💼 Client 2 · 👨💼 Client 3
Appliquez des couleurs personnalisées : Cadre à gauche du libellé, Personnaliser, Arrière-plan #ffffff Texte, mettez le code couleur que vous souhaitez, OK. #e07878 · #e09a50 · #6098e0 · #6ec860 · #e878b8
Sélectionnez I18:I50 → Données > Validation des données > Ajouter une règle.
Options avancées → Style d'affichage → Flèche.
Entrez vos catégories, leur couleur (n'oubliez pas de mettre #ffffff pour l'Arrière-plan), puis OK.
Exemples de catégories :
💳 Crédits #e07878 · 🏠 Factures Maison #e09a50 · 🛡️ Assurances #6098e0 · 💊 Prévoyance #6ec860 · 🐖 Épargne #e878b8 · 🏦 Banque #c8c040 · 👶 Enfants #40b8b8 · 📱 Abonnements #a878d8 · 📦 Autre · 💧 Eau · 🔥 Gaz · ⚡ Électricité · 🏛️ Impôts · 📋 Taxe Foncière · 🏡 Taxe d'Habitation · 👶 Garde d'enfants · ⚖️ Pension Alimentaire · 💊 Remboursement Santé · 📺 Streaming · 🏋️ Sport · 🅿️ Parking · 🛡️ Assurance Vie · 🎓 Prêt Étudiant
Et sélectionnez votre catégorie dans le menu déroulant, pour chaque Nom.
Ajoutez ensuite un numéro dans la colonne H selon votre ordre de priorité (ex. 1 pour les Crédits, 2 pour les Factures, 3 pour les Assurances…). Cela permettra de trier dans le bon ordre lors du tri alphabétique, tout en laissant les catégories propres. Et il nous suffira ensuite de masquer la colonne.
Pour trier : sélectionnez G18:J50 → clic droit → Afficher plus d'actions sur les cellules → Trier une plage : Colonne H → De A à Z. Ajouter une colonne pour le tri → Colonne J (Mensuel) → De Z à A → Trier.
Sélectionner la colonne H, Clic droit → Masquer la colonne.
Sélectionnez V18:V50 → Ajouter une règle.
Dans Critères, choisissez Menu déroulant (depuis une plage).
Sélectionnez la plage M18:M50 (catégories Budget Prévu).
Style d'affichage → Flèche. Appliquez les couleurs et validez → OK.
Exemples de catégories et couleurs : 🛒 Courses #e07878 · 🎉 Plaisirs #c8c040 · ⛽ Essence #e09a50 · 🛍️ Vêtements #6098e0 · 🌿 Entretien Jardin #6ec860 · 🐾 Croquettes #a878d8 · 🩷 Santé #e878b8 · ✂️ Coiffeur #40b8b8 · 📦 Autre #434343 5 6
Dans la cellule S18, tapez : =DATE(ANNEE(B41); MOIS(B41); T18)
DATE construit une date complète. ANNEE et MOIS extraient l'année et le mois depuis le cadre Date, et T18 fournit le jour.
Appuyez sur Entrée. La cellule S18 affiche maintenant la date complète à partir de T18 et B41.
Sélectionnez toute la colonne S (S18 + Ctrl + Shift + ↓).
Format > Nombre > Date et heure personnalisées.
Choisissez un format du type "mar. 5 août" → Appliquer.
Modifiez la formule en S18 :
=SI(T18<>""; DATE(ANNEE(B41); MOIS(B41); T18); "")
SI vérifie une condition : si T18 est différent de vide, on affiche la date, sinon la cellule reste vide.
Pour éviter les décalages de mois lors du copier-coller, utilisez ARRAYFORMULA :
=ARRAYFORMULA(SI(T18:T<>""; DATE(ANNEE(B41); MOIS(B41); T18:T); ""))
ARRAYFORMULA applique la même formule à toute la colonne automatiquement, sans avoir besoin de la copier ligne par ligne.
Maintenez Ctrl (ou ⌘ Cmd sur Mac) et sélectionnez :
D16:E29, D33:E33, D35:E39, J16:K16, J18:K50, N16:Q16, N18:Q50, W16, W18:W50
Format → Nombre → Format numérique personnalisé.
Collez ce format : _(€* #,##0.00_);_(€* (#,##0.00);_(€* "-"??.00_);_(@_)
Format monétaire personnalisé : les positifs s'affichent avec €, les négatifs entre parenthèses, les zéros avec un tiret.
Résultat : Positif → € 1 234,56 · Négatif → € (1 234,56) · Zéro → € −,00
Dans la partie négative, supprimez les parenthèses et ajoutez un signe moins :
_(€* #,##0.00_);_(€* -#,##0.00;_(€* "-"??.00_);_(@_)
Version modifiée : les négatifs s'affichent avec un signe moins au lieu de parenthèses.
Résultat : € -1 234,56
_(€* #,##0.00_);_(€* -#,##0.00;_(* ""??_);_(@_)
Les zéros sont maintenant masqués — la cellule paraît vide quand il n'y a pas de montant.
Cliquez sur Appliquer. Tous les zéros disparaissent.
Sélectionnez : D22:E23, P16:Q16, P18:Q50, W16
Format → Nombre → Format numérique personnalisé.
Appliquez : _(€* #,##0.00_);_(€* -#,##0.00;_(€* ""??0.00_);_(@_) 8
Ce format ré-affiche les zéros avec le symbole € — utile pour les cellules où le « 0,00 € » est une information importante.
P18:Q50 les zéros ne s'affichent pas encore, c'est normal — la liaison avec la colonne Montant n'est pas encore faite. Cela arrive à l'étape suivante.
En P18, saisissez : =SOMME.SI(V18:V; M18; W18:W)
SOMME.SI additionne les montants de W uniquement pour les lignes où la catégorie en V correspond à celle de M18.
P18) passe à 50.=ARRAYFORMULA(SOMME.SI(V18:V; M18:M; W18:W))
ARRAYFORMULA étend la formule SOMME.SI à toute la colonne automatiquement.
=ARRAYFORMULA(SI(M18:M<>""; SOMME.SI(V18:V; M18:M; W18:W); ""))
SI masque le résultat quand la catégorie est vide — la cellule reste propre au lieu d'afficher 0.
En Q18, saisissez : =ARRAYFORMULA(SI(M18:M<>""; N18:N-P18:P; ""))
Calcule le restant (budget mensuel − dépenses réelles) pour chaque ligne où une catégorie existe.
Ajoutez une nouvelle catégorie dans M (Budget prévu) avec sa mensualité dans N. Ajoutez-la ensuite dans V (Dépenses) avec une dépense dans W.
Vérifiez que Actuel (P) se cumule correctement et que Restant (Q) se met à jour. 9
Sélectionnez D26:E29, Q16, Q18:Q50.
Menu Format > Mise en forme conditionnelle.
Supérieur ou égal à 0 → Texte italique + vert #2e9e6b, Couleur de remplissage : aucune → OK. ✅
Ajouter une règle : Inférieur à 0 → Texte italique + rouge #d4603a, Couleur de remplissage : aucune → OK. ❌
Q18 et Q16 passent en rouge. Ajoutez ensuite le montant nécessaire pour dépasser les revenus → D28:E29 passe aussi en rouge.W16)Sélectionnez W16 → Format > Mise en forme conditionnelle.
Règle 1 : Inférieur ou égal à → formule : =D16-D18
Format : texte italique vert #2e9e6b, Couleur de remplissage : aucune → OK.
Sert de seuil : revenus − prélèvements = le maximum de dépenses à ne pas dépasser.
Règle 2 : Supérieur à → même formule : =D16-D18
Format : texte italique rouge #d4603a, Couleur de remplissage : aucune → OK.
Ajoutez un montant supérieur au Budget Prévu et n'oubliez pas de mettre une Catégorie → le Budget Prévu devient négatif (rouge), le Budget Disponible Restant reste positif (vert).
Ajoutez ensuite un montant supplémentaire → Dépenses du Mois (W16) et Budget Disponible Restant (D28:E29) passent bien en rouge. 10
Sélectionnez I18:J50. Menu Insertion > Graphique.
Onglet Configurer → Type : Graphique à secteurs en 3D. Libellé : I18:I50 · Valeur : J18:J50 · Cochez Données cumulées.
Personnaliser : Style de graphique → Couleur de la bordure → #f7cec3. Libellé de secteur : Aucun.
Couleurs manuelles : 💳 Crédits #ffdbdb · 🏠 Factures #ffeddb · 🛡️ Assurances #dbeaff · 💊 Prévoyance #e0ffdb · 🐖 Épargne #ffdbef · 🏦 Banque #fffcdb · 👶 Enfants #dbffff · 📱 Abonnements #eddbff
Légende → Couleur du texte → #434343. Placez le graphique sur G2:K12.
Sélectionnez M18:N50. Menu Insertion > Graphique.
Type : Graphique à secteurs en 3D. Libellé : M18:M50 · Valeur : N18:N50. Ne cochez pas Données cumulées cette fois.
Personnaliser : Bordure → #f7deb6. Couleurs manuelles : 🛒 Courses #ffdbdb · 🎉 Plaisirs #fffcdb · ⛽ Essence #ffeddb · 🛍️ Vêtements #dbeaff · 🌿 Jardin #e0ffdb · 🐾 Croquettes #eddbff · 🩷 Santé #ffdbef · ✂️ Coiffeur #dbffff · 📦 Autre #ededed
Placez le graphique sur M2:Q12.
Sélectionnez M18:M50 et P18:P50.
Type : Graphique à barres. Style : Bordure #bcdefa, 3D.
Série → Mettre en forme le point de données → assignez les couleurs.
Légende → #434343. Axe horizontal → Format numérique : Devise (arrondi). Quadrillage → #d9d9d9.
Placez le graphique sur S2:W12.
Sélectionnez B16:E29. Type : Graphique à colonnes.
Style : Bordure #cad9e5, 3D. Couleurs : #c4ecda · #f7cec3 · #f7deb6 · #bcdefa · #ddeaf2 · #f0d8ec · #d2c4e3
Cocher Libellés de données, Position Centrer, Taille 12, Gras & italique, Couleur #434343.
Axe horizontal et vertical → Couleur du texte → blanc. Quadrillage → #d9d9d9.
Placez le graphique sur B2:E12. 11
Menu Affichage > Afficher > Quadrillage (décochez).
Votre tableur garde uniquement vos bordures personnalisées et vos couleurs, ce qui le rend beaucoup plus lisible et propre.
En bas de l'écran, double-cliquez sur le nom de l'onglet (par défaut "Feuille 1").
Tapez un nom clair, par exemple Mai.
Cela permet de retrouver vos feuilles facilement.
D26:E27 ? Elle utilise SIERREUR pour aller chercher le solde du mois précédent. Pour l'instant elle reste vide parce que l'onglet du mois précédent n'existe pas encore — c'est exactement le comportement prévu. Le jour où vous créerez vos prochains mois, tout se remplira automatiquement.12
La deuxième page de votre tableur : une vue d'ensemble de toute l'année.
En bas de l'écran, double-cliquez sur l'onglet "Feuille 2" → tapez Visuel Annuel → Entrée.
Sélectionnez toute la feuille → Aligner horizontalement → Centre → Aligner verticalement → Milieu.
Sélectionnez B2:M3 → Fusionnez les cellules → tapez VISUEL ANNUEL 2026.
Gras, taille 14. Fond #7ab8e0, texte blanc.
Colonne A et I → Clic droit, Redimensionner → 30.
Colonnes B, C, D, E, F, G, H, J, K, L, M → 195.
Le premier tableau montre le flux du mois (ce qui entre, ce qui sort, ce qu'il reste), le deuxième montre la tendance sur l'année (progression, taux, cumul). 13
Fusionnez B19:B20 et copiez-collez en C19, D19, E19, F19, G19, H19, J19, K19, L19 et M19.
Puis copier B19:M20 et coller en B21, et en B23.
Couleurs de remplissage des en-têtes :
B19:B20 et J19:J20 #ddeaf2 · C19:C20 #d6f2e6 · D19:D20 #fae0d6 · E19:E20 #fae8cc · F19:F20 #d0e8fc · G19:G20 #d5dbf2 · H19:H20 #dfd4ed · K19:K20 #faedf5 · L19:L20 #faeeda · M19:M20 #e1f5ee
Lignes zébrées :
B21:B22 et J21:J22 #f2f7fb · C21:C22 #f4fcf8 · D21:D22 #fef8f5 · E21:E22 #fef9f3 · F21:F22 #f3f9fe · G21:G22 #f4f5fc · H21:H22 #f9f7fc · K21:K22 #fef8fb · L21:L22 #fdf8ee · M21:M22 #f4fcf8
Copier B21:M24 et coller en B25, B29, B33, B37 et B41. Puis copier B43:M44 et coller en B45.
Total :
B45:B46 et J45:J46 #e8f1f7 · C45:C46 #eaf8f1 · D45:D46 #fdf0eb · E45:E46 #fdf4e8 · F45:F46 #e8f3fd · G45:G46 #e6e9f8 · H45:H46 #f4f0fa · K45:K46 #fcf2f8 · L45:L46 #fbf2e4 · M45:M46 #eaf9f3
Style de la bordure, 2ème trait. Couleur de la bordure personnalisée :
#b8c8d8 Bordure inférieure B19:B20 et J19:J20 — Bordure supérieure B45:B46 et J45:J46
#b2e5d0 Bordure inférieure C19:C20 — Bordure supérieure C45:C46
#f5c4b0 Bordure inférieure D19:D20 — Bordure supérieure D45:D46
#f5d4a0 Bordure inférieure E19:E20 — Bordure supérieure E45:E46
#a8d5f7 Bordure inférieure F19:F20 — Bordure supérieure F45:F46
#c0c8e8 Bordure inférieure G19:G20 — Bordure supérieure G45:G46
#c4b8e0 Bordure inférieure H19:H20 — Bordure supérieure H45:H46
#f0c8dc Bordure inférieure K19:K20 — Bordure supérieure K45:K46
#e8d4a0 Bordure inférieure L19:L20 — Bordure supérieure L45:L46
#9fe1cb Bordure inférieure M19:M20 — Bordure supérieure M45:M46
Désactivez le quadrillage → Affichage > Afficher > Quadrillage.
Bordures intérieures, 1er trait, en blanc dans les zones colorées : B19:H20, J19:M20, B45:H46 et J45:M46
Bordures intérieures en gris clair 2 (#efefef) dans les zones de données : B21:H44 et J21:M44
Bordure gauche en #efefef : B21:B44 et J21:J44
Bordure droite en #efefef : H21:H44 et M21:M44
Réactivez le quadrillage. 14
B19:B20 📅 MOIS #2a4a5a · C19:C20 REVENUS #1a5e3f · D19:D20 PRÉLÈVEMENTS #7a2e1a · E19:E20 FONDS DISPONIBLES #7a4400 · F19:F20 DÉPENSES DU MOIS #1a3f7a · G19:G20 DÉPENSES TOTALES #2e3570 · H19:H20 FONDS RESTANTS #4a2e7a
K19:K20 ÉCART #6a2040 · L19:L20 TAUX D'ÉPARGNE #7a5500 · M19:M20 SOLDE CUMULÉ #0f6e56
B21:B44 : Janvier à Décembre — #2a4a5a
B45:B46 : TOTAL ANNUEL — #2a4a5a
B47 : Moyenne/mois — #999999 (toute la ligne B47:H47)
Copier B19:B46 et coller à J19.
Les en-têtes ligne 19, le Total Annuel, les montants ligne 45, et les mois B21:B44 et J21:J44 : en gras, taille 11.
B47:H47 : taille 10, italique.
C21:H44 et K21:M44 : en gras, taille 10. 15
Clic droit sur les colonnes correspondantes → Insérer une remarque :
C — Revenus : Récupère vos revenus du mois sur sa page correspondante.
D — Prélèvements : Récupère vos prélèvements automatiques du mois sur sa page correspondante.
E — Fonds Disponibles : Revenus - Prélèvements. Votre enveloppe réelle pour le mois, avant de dépenser.
F — Dépenses du Mois : Récupère vos dépenses du mois sur sa page correspondante.
G — Dépenses Totales : Prélèvements + Dépenses. Tout ce qui est sorti dans le mois.
H — Fonds Restants : Fonds Disponibles - Dépenses. Ce que vous avez gardé à la fin du mois.
K — Écart : Fonds Restants de ce mois - mois précédent. Positif = vous avez gardé plus. Négatif = vous avez gardé moins.
L — Taux d'Épargne : Fonds Restants ÷ Revenus × 100. Le pourcentage de vos revenus conservé ce mois.
M — Solde Cumulé : Cumul de vos fonds restants depuis janvier. Ce que vous avez réellement mis de côté sur l'année.
C21 =SIERREUR(INDIRECT("'Janvier'!D16");"")
SIERREUR(… ; "") → protège si l'onglet Janvier n'existe pas encore. Pas d'erreur, ça reste vide.
C'est le même schéma SIERREUR qu'on a utilisé pour le report — on le retrouvera sur plusieurs formules ici.
INDIRECT force Google Sheets à vérifier l'onglet à chaque recalcul. Sans lui, si vous créez un nouvel onglet, les cellules du nouveau mois resteraient vides parce que Google Sheets aura mémorisé l'absence — il faudrait les réveiller une par une. Avec INDIRECT, tout se remplit automatiquement dès que l'onglet existe.
D21 =SIERREUR(INDIRECT("'Janvier'!D18");"")
E21 =SI(C21="";"";C21-D21)
Si les revenus sont vides (mois pas rempli), la cellule reste vide. Sinon, ça calcule revenus − prélèvements.
F21 =SIERREUR(INDIRECT("'Janvier'!D22");"")
G21 =SI(C21="";"";D21+F21)
Si les revenus sont vides, reste vide. Sinon, ça additionne prélèvements + dépenses du mois = total des dépenses.
H21 =SI(C21="";"";E21-F21)
Si les revenus sont vides, reste vide. Sinon, ça calcule fonds disponibles − dépenses = ce que vous avez gardé.
K21 (vide - pas de mois précédent)
L21 =SIERREUR(SI(C21="";"";H21/C21*100);"")
Si les revenus sont vides, ça reste vide. Sinon, ça calcule le taux d'épargne : fonds restants ÷ revenus × 100 = le pourcentage que vous avez conservé ce mois.
M21 =SI(H21="";"";H21)
Point de départ du cumul — pour janvier, le cumul est simplement égal aux fonds restants du mois.
C23 =SIERREUR(INDIRECT("'Février'!D16");"")
D23 =SIERREUR(INDIRECT("'Février'!D18");"")
E23 =SI(C23="";"";C23-D23)
F23 =SIERREUR(INDIRECT("'Février'!D22");"")
G23 =SI(C23="";"";D23+F23)
H23 =SI(C23="";"";E23-F23)
K23 =SI(OU(H23="";H21="");"";H23-H21)
OU vérifie que les deux mois sont remplis. Si l'un des deux est vide, pas de calcul. Sinon, l'écart = fonds restants de ce mois − fonds restants du mois précédent.
L23 =SIERREUR(SI(C23="";"";H23/C23*100);"")
M23 =SI(H23="";"";M21+H23)
Ajoute les fonds restants du mois au cumul du mois précédent — votre épargne cumulée grandit mois après mois.
C25 =SIERREUR(INDIRECT("'Mars'!D16");"")
D25 =SIERREUR(INDIRECT("'Mars'!D18");"")
E25 =SI(C25="";"";C25-D25)
F25 =SIERREUR(INDIRECT("'Mars'!D22");"")
G25 =SI(C25="";"";D25+F25)
H25 =SI(C25="";"";E25-F25)
K25 =SI(OU(H25="";H23="");"";H25-H23)
L25 =SIERREUR(SI(C25="";"";H25/C25*100);"")
M25 =SI(H25="";"";M23+H25)
C27 =SIERREUR(INDIRECT("'Avril'!D16");"")
D27 =SIERREUR(INDIRECT("'Avril'!D18");"")
E27 =SI(C27="";"";C27-D27)
F27 =SIERREUR(INDIRECT("'Avril'!D22");"")
G27 =SI(C27="";"";D27+F27)
H27 =SI(C27="";"";E27-F27)
K27 =SI(OU(H27="";H25="");"";H27-H25)
L27 =SIERREUR(SI(C27="";"";H27/C27*100);"")
M27 =SI(H27="";"";M25+H27)
C29 =SIERREUR(INDIRECT("'Mai'!D16");"")
D29 =SIERREUR(INDIRECT("'Mai'!D18");"")
E29 =SI(C29="";"";C29-D29)
F29 =SIERREUR(INDIRECT("'Mai'!D22");"")
G29 =SI(C29="";"";D29+F29)
H29 =SI(C29="";"";E29-F29)
K29 =SI(OU(H29="";H27="");"";H29-H27)
L29 =SIERREUR(SI(C29="";"";H29/C29*100);"")
M29 =SI(H29="";"";M27+H29)
C31 =SIERREUR(INDIRECT("'Juin'!D16");"")
D31 =SIERREUR(INDIRECT("'Juin'!D18");"")
E31 =SI(C31="";"";C31-D31)
F31 =SIERREUR(INDIRECT("'Juin'!D22");"")
G31 =SI(C31="";"";D31+F31)
H31 =SI(C31="";"";E31-F31)
K31 =SI(OU(H31="";H29="");"";H31-H29)
L31 =SIERREUR(SI(C31="";"";H31/C31*100);"")
M31 =SI(H31="";"";M29+H31)
C33 =SIERREUR(INDIRECT("'Juillet'!D16");"")
D33 =SIERREUR(INDIRECT("'Juillet'!D18");"")
E33 =SI(C33="";"";C33-D33)
F33 =SIERREUR(INDIRECT("'Juillet'!D22");"")
G33 =SI(C33="";"";D33+F33)
H33 =SI(C33="";"";E33-F33)
K33 =SI(OU(H33="";H31="");"";H33-H31)
L33 =SIERREUR(SI(C33="";"";H33/C33*100);"")
M33 =SI(H33="";"";M31+H33)
C35 =SIERREUR(INDIRECT("'Août'!D16");"")
D35 =SIERREUR(INDIRECT("'Août'!D18");"")
E35 =SI(C35="";"";C35-D35)
F35 =SIERREUR(INDIRECT("'Août'!D22");"")
G35 =SI(C35="";"";D35+F35)
H35 =SI(C35="";"";E35-F35)
K35 =SI(OU(H35="";H33="");"";H35-H33)
L35 =SIERREUR(SI(C35="";"";H35/C35*100);"")
M35 =SI(H35="";"";M33+H35)
C37 =SIERREUR(INDIRECT("'Septembre'!D16");"")
D37 =SIERREUR(INDIRECT("'Septembre'!D18");"")
E37 =SI(C37="";"";C37-D37)
F37 =SIERREUR(INDIRECT("'Septembre'!D22");"")
G37 =SI(C37="";"";D37+F37)
H37 =SI(C37="";"";E37-F37)
K37 =SI(OU(H37="";H35="");"";H37-H35)
L37 =SIERREUR(SI(C37="";"";H37/C37*100);"")
M37 =SI(H37="";"";M35+H37)
C39 =SIERREUR(INDIRECT("'Octobre'!D16");"")
D39 =SIERREUR(INDIRECT("'Octobre'!D18");"")
E39 =SI(C39="";"";C39-D39)
F39 =SIERREUR(INDIRECT("'Octobre'!D22");"")
G39 =SI(C39="";"";D39+F39)
H39 =SI(C39="";"";E39-F39)
K39 =SI(OU(H39="";H37="");"";H39-H37)
L39 =SIERREUR(SI(C39="";"";H39/C39*100);"")
M39 =SI(H39="";"";M37+H39)
C41 =SIERREUR(INDIRECT("'Novembre'!D16");"")
D41 =SIERREUR(INDIRECT("'Novembre'!D18");"")
E41 =SI(C41="";"";C41-D41)
F41 =SIERREUR(INDIRECT("'Novembre'!D22");"")
G41 =SI(C41="";"";D41+F41)
H41 =SI(C41="";"";E41-F41)
K41 =SI(OU(H41="";H39="");"";H41-H39)
L41 =SIERREUR(SI(C41="";"";H41/C41*100);"")
M41 =SI(H41="";"";M39+H41)
C43 =SIERREUR(INDIRECT("'Décembre'!D16");"")
D43 =SIERREUR(INDIRECT("'Décembre'!D18");"")
E43 =SI(C43="";"";C43-D43)
F43 =SIERREUR(INDIRECT("'Décembre'!D22");"")
G43 =SI(C43="";"";D43+F43)
H43 =SI(C43="";"";E43-F43)
K43 =SI(OU(H43="";H41="");"";H43-H41)
L43 =SIERREUR(SI(C43="";"";H43/C43*100);"")
M43 =SI(H43="";"";M41+H43)
C45 =SOMME(C21:C44)
D45 =SOMME(D21:D44)
E45 =SOMME(E21:E44)
F45 =SOMME(F21:F44)
G45 =SOMME(G21:G44)
H45 =SOMME(H21:H44)
K45 (vide)
L45 =SIERREUR(SI(C45="";"";H45/C45*100);"")
M45 =SIERREUR(RECHERCHE(9,99E+307;M21:M44);"")
Alors ça, c'est une astuce. La fonction RECHERCHE est faite pour chercher une valeur dans une plage triée. En lui donnant un nombre très élevé qu'elle ne trouvera jamais, elle parcourt toute la colonne et renvoie la dernière valeur. C'est comme ça qu'on récupère votre solde cumulé le plus récent.
Parce qu'il n'existe pas de fonction native dans Google Sheets qui dit « donne-moi la dernière valeur d'une colonne ».
Cette astuce est devenue un standard — c'est la façon la plus courte et la plus fiable de le faire.
C47 =SI(C45="";"";C45/NB(C21:C43))
NB compte uniquement les cellules contenant un nombre — la moyenne reste juste même si tous les mois ne sont pas encore remplis.
D47 à H47 → glisser-déposer depuis C47
Sélectionnez C21:H47, K21:K44 et M21:M46.
Format > Nombre > Format numérique personnalisé :
#,##0.00;-#,##0.00;"";@
Format numérique sans symbole € — plus compact, adapté au Visuel Annuel.
Pour L21:L46 : #,##0.0" %";-#,##0.0" %";"";@
Format pourcentage avec une décimale, zéros masqués — pour la colonne Taux d'Épargne.
Sélectionnez H21:H46 + K21:K44 + L21:L46 + M21:M46.
Format > Mise en forme conditionnelle.
Règle 1 : Supérieur ou égal à 0 → texte italique, couleur #2e9e6b (vert), remplissage : aucune → OK.
Règle 2 : Inférieur à 0 → texte italique, couleur #d4603a (corail), remplissage : aucune → OK. 16
Sélectionnez B21:B44, C21:C44 et G21:G44. Type : Graphique à colonnes.
Bordure #c4ecda, 3D. Série 1 #c4ecda · Série 2 #d5dbf2. Légende : Aucune.
Axe horizontal → #2a4a5a. Axe vertical → #434343, Devise (arrondi). Quadrillage → #efefef.
Sélectionnez B21:B44, D21:D44 et F21:F44. Type : Histogramme empilé.
Bordure #fae0d6, 3D. Série 1 #f7cec3 · Série 2 #bcdefa. Légende : Aucune.
Axe horizontal → #2a4a5a. Axe vertical → #434343, Devise (arrondi). Quadrillage → #efefef.
Sélectionnez B21:B44 et H21:H44. Type : Courbes lissées.
Bordure #dfd4ed. Couleur de ligne #d2c4e3, épaisseur 2px, points carrés 7px.
Axe horizontal → #2a4a5a. Axe vertical → #434343, Devise (arrondi). Quadrillage → #efefef.
Fusionnez N21:N22, O21:O22, P21:P22, Q21:Q22. Formules :
=SI(K21>=0;K21;0) en N21 (Écart positif)
Sépare les valeurs positives : si l'écart est positif ou nul on le garde, sinon on met 0. Cela permet de créer deux séries distinctes pour le graphique.
=SI(K21<0;K21;0) en O21 (Écart négatif)
=SI(M21>=0;M21;0) en P21 (Cumul positif)
=SI(M21<0;M21;0) en Q21 (Cumul négatif)
Glisser N21:Q22 jusqu'à N43:Q44. Sélectionner N21:Q44 → Couleur du texte : blanc.
Sélectionnez J21:J44, N21:N44, O21:O44. Type : Histogramme empilé.
Bordure #f0c8dc. Série 1 #b2e5d0 · Série 2 #f5c4b0. Légende : Aucune.
Axe horizontal → #2a4a5a. Axe vertical → #434343, Devise (arrondi). Quadrillage → #efefef.
Sélectionnez J21:J44, P21:P44, Q21:Q44. Type : Histogramme empilé.
Bordure #bee9d6. Série 1 #b2e5d0 · Série 2 #f5c4b0. Légende : Aucune.
Axe horizontal → #2a4a5a. Axe vertical → #434343, Devise (arrondi). Quadrillage → #efefef.
Affichage > Afficher > Quadrillage (décochez).
Supprimez les colonnes inutiles à partir de S (cliquer sur S, Ctrl + Shift + droite, clic droit, Supprimer).
Supprimez les lignes inutiles à partir de 56 (cliquer sur 56, Ctrl + Shift + bas, clic droit, Supprimer). 17
Clic droit sur l'onglet de votre dernier mois → Dupliquer.
Double-cliquez sur le nom du nouvel onglet et tapez le nom du mois suivant.
Modifiez la date dans le cadre Date (B41:E50) pour qu'elle corresponde au nouveau mois.
Videz le tableau Dépenses du Mois T18:W50 (les colonnes Jour, Nom, Catégorie, Montant).
Bravo 👏 vous venez de créer votre tableur complet de gestion budgétaire avec son Visuel Annuel !